home *** CD-ROM | disk | FTP | other *** search
/ SGI Freeware 1999 August / SGI Freeware 1999 August.iso / dist / fw_emacs.idb / usr / freeware / share / emacs / 19.34 / lisp / xt-mouse.el.z / xt-mouse.el
Encoding:
Text File  |  1998-10-28  |  6.0 KB  |  191 lines
  1. ;;; xt-mouse.el --- Support the mouse when emacs run in an xterm.
  2.  
  3. ;; Copyright (C) 1994 Free Software Foundation
  4.  
  5. ;; Author: Per Abrahamsen <abraham@iesd.auc.dk>
  6. ;; Keywords: mouse, terminals
  7.  
  8. ;; This file is part of GNU Emacs.
  9.  
  10. ;; GNU Emacs is free software; you can redistribute it and/or modify
  11. ;; it under the terms of the GNU General Public License as published by
  12. ;; the Free Software Foundation; either version 2, or (at your option)
  13. ;; any later version.
  14.  
  15. ;; GNU Emacs is distributed in the hope that it will be useful,
  16. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18. ;; GNU General Public License for more details.
  19.  
  20. ;; You should have received a copy of the GNU General Public License
  21. ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22. ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23. ;; Boston, MA 02111-1307, USA.
  24.  
  25. ;;; Comments:
  26.  
  27. ;; Enable mouse support when running inside an xterm or Linux console.
  28.  
  29. ;; This is actually useful when you are running X11 locally, but is
  30. ;; working on remote machine over a modem line or through a gateway.
  31.  
  32. ;; It works by translating xterm escape codes into generic emacs mouse
  33. ;; events so it should work with any package that uses the mouse.
  34.  
  35. ;; The xterm mouse escape codes are supposedly also supported by the
  36. ;; Linux console, but I have not been able to verify this.
  37.  
  38. ;; You don't have to turn off xterm mode to use the normal xterm mouse
  39. ;; functionality, it is still available by holding down the SHIFT key
  40. ;; when you press the mouse button.
  41.  
  42. ;;; Todo:
  43.  
  44. ;; Support multi-click -- somehow.
  45.  
  46. ;; Clicking on the mode-line does not work, although it should.
  47.  
  48. ;;; Code: 
  49.  
  50. (define-key function-key-map "\e[M" 'xterm-mouse-translate)
  51.  
  52. (defvar xterm-mouse-last)
  53.  
  54. (defun xterm-mouse-translate (event)
  55.   ;; Read a click and release event from XTerm.
  56.   (save-excursion
  57.     (save-window-excursion
  58.       (deactivate-mark)
  59.       (let* ((xterm-mouse-last)
  60.          (down (xterm-mouse-event))
  61.          (down-command (nth 0 down))
  62.          (down-data (nth 1 down))
  63.          (down-where (nth 1 down-data))
  64.          (down-binding (key-binding (if (symbolp down-where)
  65.                         (vector down-where down-command)
  66.                       (vector down-command)))))
  67.     (or (and (eq (read-char) ?\e)
  68.          (eq (read-char) ?\[)
  69.          (eq (read-char) ?M))
  70.         (error "Unexpected escape sequence from XTerm"))
  71.     (let* ((click (xterm-mouse-event))
  72.            (click-command (nth 0 click))
  73.            (click-data (nth 1 click))
  74.            (click-where (nth 1 click-data)))
  75.       (if (memq down-binding '(nil ignore))
  76.           (if (and (symbolp click-where)
  77.                (not (eq 'menu-bar click-where)))
  78.           (vector (list click-where click-data) click)
  79.         (vector click))
  80.         (setq unread-command-events
  81.           (if (eq down-where click-where)
  82.               (list click)
  83.             (list
  84.              ;; Cheat `mouse-drag-region' with move event.
  85.              (list 'mouse-movement click-data)
  86.              ;; Generate a drag event.
  87.              (if (symbolp down-where)
  88.              0
  89.                (list (intern (concat "drag-mouse-" (+ 1 xterm-mouse-last)))
  90.                  down-data click-data))
  91.              )))
  92.         (if (and (symbolp down-where)
  93.              (not (eq 'menu-bar down-where)))
  94.         (vector (list down-where down-data) down)
  95.           (vector down))))))))
  96.  
  97. (defvar xterm-mouse-x 0
  98.   "Position of last xterm mouse event relative to the frame.")
  99.  
  100. (defvar xterm-mouse-y 0
  101.   "Position of last xterm mouse event relative to the frame.")
  102.  
  103. (defadvice mouse-position (around xterm-mouse activate)
  104.   "Use last key from xterm-mouse-mode if available."
  105.   (let ((answer ad-do-it))
  106.     (setq ad-return-value
  107.       (if xterm-mouse-mode
  108.           (cons (car answer) (cons xterm-mouse-x xterm-mouse-y))
  109.         answer))))
  110.  
  111. (defun xterm-mouse-event ()
  112.   ;; Convert XTerm mouse event to Emacs mouse event.
  113.   (let* ((type (- (read-char) ? ))
  114.      (x (- (read-char) ?  1))
  115.      (y (- (read-char) ?  1))
  116.      (point (cons x y))
  117.      (window (window-at x y))
  118.      (where (if window 
  119.             (coordinates-in-window-p point window)
  120.           'menu-bar))
  121.      (pos (if (consp where)
  122.           (progn
  123.             (select-window window)
  124.             (goto-char (window-start window))
  125.             (move-to-window-line  (cdr where))
  126.             (move-to-column (+ (car where) (current-column)
  127.                        (if (string-match "\\` \\*Minibuf"
  128.                              (buffer-name))
  129.                        (- (minibuffer-prompt-width))
  130.                      0)
  131.                        (max 0 (1- (window-hscroll)))))
  132.             (point))
  133.         where))
  134.      (mouse (intern (if (eq type 3)
  135.                 (concat "mouse-" (+ 1 xterm-mouse-last))
  136.               (setq xterm-mouse-last type)
  137.               (concat "down-mouse-" (+ 1 type))))))
  138.     (setq xterm-mouse-x x
  139.       xterm-mouse-y y)
  140.     (list mouse
  141.       (list window pos point
  142.         (/ (nth 2 (current-time)) 1000)))))
  143.  
  144. ;; Indicator for the xterm-mouse mode.
  145. (defvar xterm-mouse-mode nil)
  146.  
  147. (or (assq 'xterm-mouse-mode minor-mode-alist)
  148.     (setq minor-mode-alist
  149.       (cons '(xterm-mouse-mode (" Mouse")) minor-mode-alist)))
  150.  
  151. ;;;###autoload
  152. (defun xterm-mouse-mode (arg)
  153.   "Toggle XTerm mouse mode.
  154. With prefix arg, turn XTerm mouse mode on iff arg is positive.
  155.  
  156. Turn it on to use emacs mouse commands, and off to use xterm mouse commands."
  157.   (interactive "P")
  158.   (if (or (and (null arg) xterm-mouse-mode)
  159.       (<= (prefix-numeric-value arg) 0))
  160.       ;; Turn it off
  161.       (if xterm-mouse-mode
  162.       (progn
  163.         (turn-off-xterm-mouse-tracking)
  164.         (setq xterm-mouse-mode nil)
  165.         (set-buffer-modified-p (buffer-modified-p))))
  166.     ;;Turn it on
  167.     (if xterm-mouse-mode
  168.     ()
  169.       (setq xterm-mouse-mode t)
  170.       (turn-on-xterm-mouse-tracking)
  171.       (set-buffer-modified-p (buffer-modified-p)))))
  172.  
  173. (defun turn-on-xterm-mouse-tracking ()
  174.   ;; Enable emacs mouse tracking in xterm.
  175.   (if xterm-mouse-mode
  176.       (send-string-to-terminal "\e[?1000h")))
  177.  
  178. (defun turn-off-xterm-mouse-tracking ()
  179.   ;; Disable disable emacs mouse tracking in xterm.
  180.   (if xterm-mouse-mode
  181.       (send-string-to-terminal "\e[?1000l")))
  182.  
  183. ;; Restore normal mouse behaviour outside Emacs.
  184. (add-hook 'suspend-hook 'turn-off-xterm-mouse-tracking)
  185. (add-hook 'suspend-resume-hook 'turn-on-xterm-mouse-tracking)
  186. (add-hook 'kill-emacs-hook 'turn-off-xterm-mouse-tracking)
  187.  
  188. (provide 'xt-mouse)
  189.  
  190. ;;; xt-mouse.el ends here
  191.